kernel3.cl 12 KB
Newer Older
Leonardo Solis's avatar
Leonardo Solis committed
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
__kernel void __attribute__ ((reqd_work_group_size(NUM_OF_THREADS_PER_BLOCK,1,1)))
perform_LS( 		 char   dockpars_num_of_atoms,
			           char   dockpars_num_of_atypes,
		             int    dockpars_num_of_intraE_contributors,
		             char   dockpars_gridsize_x,
       			     char   dockpars_gridsize_y,
        	     	 char   dockpars_gridsize_z,
        		     float  dockpars_grid_spacing,

		#if defined (RESTRICT_ARGS)
  __global const float* restrict dockpars_fgrids, // cannot be allocated in __constant (too large)
		#else
  __global const float* dockpars_fgrids,          // cannot be allocated in __constant (too large)
		#endif

	              int    dockpars_rotbondlist_length,
  			        float  dockpars_coeff_elec,
			          float  dockpars_coeff_desolv,

		#if defined (RESTRICT_ARGS)
		__global float* restrict dockpars_conformations_next,
    __global float* restrict dockpars_energies_next,
	  __global int*   restrict dockpars_evals_of_new_entities,
	  __global unsigned int* restrict dockpars_prng_states,
		#else
	 	    __global float* dockpars_conformations_next,
        __global float* dockpars_energies_next,
	      __global int*   dockpars_evals_of_new_entities,
		    __global unsigned int* dockpars_prng_states,
		#endif

		       	    int    dockpars_pop_size,
			          int    dockpars_num_of_genes,
			          float  dockpars_lsearch_rate,
			          unsigned int dockpars_num_of_lsentities,
			          float  dockpars_rho_lower_bound,
			          float  dockpars_base_dmov_mul_sqrt3,
			          float  dockpars_base_dang_mul_sqrt3,
			          unsigned int dockpars_cons_limit,
			          unsigned int dockpars_max_num_of_iters,
			          float  dockpars_qasp,

	        __constant float* atom_charges_const,
          __constant char*  atom_types_const,
	        __constant char*  intraE_contributors_const,
          __constant float* VWpars_AC_const,
          __constant float* VWpars_BD_const,
          __constant float* dspars_S_const,
          __constant float* dspars_V_const,
          __constant int*   rotlist_const,
          __constant float* ref_coords_x_const,
          __constant float* ref_coords_y_const,
          __constant float* ref_coords_z_const,
          __constant float* rotbonds_moving_vectors_const,
          __constant float* rotbonds_unit_vectors_const,
          __constant float* ref_orientation_quats_const
)
//The GPU global function performs local search on the pre-defined entities of conformations_next.
//The number of blocks which should be started equals to num_of_lsentities*num_of_runs.
//This way the first num_of_lsentities entity of each population will be subjected to local search
//(and each block carries out the algorithm for one entity).
//Since the first entity is always the best one in the current population,
//it is always tested according to the ls probability, and if it not to be
//subjected to local search, the entity with ID num_of_lsentities is selected instead of the first one (with ID 0).
{
	__local float genotype_candidate[ACTUAL_GENOTYPE_LENGTH];
	__local float genotype_deviate  [ACTUAL_GENOTYPE_LENGTH];
	__local float genotype_bias     [ACTUAL_GENOTYPE_LENGTH];
  __local float rho;
	__local int   cons_succ;
	__local int   cons_fail;
	__local int   iteration_cnt;
	__local float candidate_energy;
	__local int   evaluation_cnt;
	int gene_counter;

	__local float offspring_genotype[ACTUAL_GENOTYPE_LENGTH];
	__local int run_id;
	__local int entity_id;
	__local float offspring_energy;

	//determining run ID and entity ID, initializing
	if (get_local_id(0) == 0)
	{
		run_id = get_group_id(0) / dockpars_num_of_lsentities;
		entity_id = get_group_id(0) % dockpars_num_of_lsentities;

		//since entity 0 is the best one due to elitism, should be subjected to random selection
		if (entity_id == 0)
			if (100.0f*gpu_randf(dockpars_prng_states) > dockpars_lsearch_rate)
				entity_id = dockpars_num_of_lsentities;	//if entity 0 is not selected according to LS rate,
									                              //choosing an other entity

		offspring_energy = dockpars_energies_next[run_id*dockpars_pop_size+entity_id];
	}

	barrier(CLK_LOCAL_MEM_FENCE);

#if defined (ASYNC_COPY)
  async_work_group_copy(offspring_genotype,
			                  dockpars_conformations_next+(run_id*dockpars_pop_size+entity_id)*GENOTYPE_LENGTH_IN_GLOBMEM,
                        dockpars_num_of_genes,0);
#else
	for (gene_counter=get_local_id(0);
	     gene_counter<dockpars_num_of_genes;
	     gene_counter+=NUM_OF_THREADS_PER_BLOCK)
		   offspring_genotype[gene_counter] = dockpars_conformations_next[(run_id*dockpars_pop_size+entity_id)*GENOTYPE_LENGTH_IN_GLOBMEM+gene_counter];
#endif

	for (gene_counter=get_local_id(0);
	     gene_counter<dockpars_num_of_genes;
	     gene_counter += NUM_OF_THREADS_PER_BLOCK)
		   genotype_bias[gene_counter] = 0.0f;

	if (get_local_id(0) == 0) {
		rho = 1.0f;
		cons_succ = 0;
		cons_fail = 0;
		iteration_cnt = 0;
		evaluation_cnt = 0;
	}

	barrier(CLK_LOCAL_MEM_FENCE);

	while ((iteration_cnt < dockpars_max_num_of_iters) && (rho > dockpars_rho_lower_bound))
	{
		//new random deviate
		for (gene_counter=get_local_id(0);
		     gene_counter<dockpars_num_of_genes;
		     gene_counter += NUM_OF_THREADS_PER_BLOCK)
		{
			genotype_deviate[gene_counter] = rho*(2*gpu_randf(dockpars_prng_states)-1);

			if (gene_counter < 3)
				genotype_deviate[gene_counter] *= dockpars_base_dmov_mul_sqrt3;
			else
				genotype_deviate[gene_counter] *= dockpars_base_dang_mul_sqrt3;
		}

		//generating new genotype candidate
		for (gene_counter=get_local_id(0);
		     gene_counter<dockpars_num_of_genes;
		     gene_counter += NUM_OF_THREADS_PER_BLOCK)
			   genotype_candidate[gene_counter] = offspring_genotype[gene_counter] + genotype_deviate[gene_counter] + genotype_bias[gene_counter];

		//evaluating candidate
		barrier(CLK_LOCAL_MEM_FENCE);

		// ==================================================================
		gpu_calc_energy(dockpars_rotbondlist_length,
				            dockpars_num_of_atoms,
				            dockpars_gridsize_x,
				            dockpars_gridsize_y,
				            dockpars_gridsize_z,
				            dockpars_fgrids,
				            dockpars_num_of_atypes,
				            dockpars_num_of_intraE_contributors,
				            dockpars_grid_spacing,
				            dockpars_coeff_elec,
        			      dockpars_qasp,
				            dockpars_coeff_desolv,
				            genotype_candidate,
				            &candidate_energy,
				            &run_id,

        			      atom_charges_const,
				            atom_types_const,
				            intraE_contributors_const,
				            VWpars_AC_const,
        			      VWpars_BD_const,
				            dspars_S_const,
				            dspars_V_const,
				            rotlist_const,
        			      ref_coords_x_const,
				            ref_coords_y_const,
				            ref_coords_z_const,
				            rotbonds_moving_vectors_const,
        			      rotbonds_unit_vectors_const,
				            ref_orientation_quats_const);
		// =================================================================

		if (get_local_id(0) == 0)
			evaluation_cnt++;

		barrier(CLK_LOCAL_MEM_FENCE);

		if (candidate_energy < offspring_energy)	//if candidate is better, success
		{
			for (gene_counter=get_local_id(0);
			     gene_counter<dockpars_num_of_genes;
			     gene_counter += NUM_OF_THREADS_PER_BLOCK)
			{
				//updating offspring_genotype
				offspring_genotype[gene_counter] = genotype_candidate[gene_counter];

				//updating genotype_bias
				genotype_bias[gene_counter] = 0.6f*genotype_bias[gene_counter] + 0.4f*genotype_deviate[gene_counter];
			}

			//thread 0 will overwrite the shared variables
			//used in the previous if condition,
			//all threads have to be after if
			barrier(CLK_LOCAL_MEM_FENCE);

			if (get_local_id(0) == 0)
			{
				offspring_energy = candidate_energy;
				cons_succ++;
				cons_fail = 0;
			}
		}
		else	//if candidate is worser, check the opposite direction
		{
			//generating the other genotype candidate
			for (gene_counter=get_local_id(0);
			     gene_counter<dockpars_num_of_genes;
			     gene_counter += NUM_OF_THREADS_PER_BLOCK)
				   genotype_candidate[gene_counter] = offspring_genotype[gene_counter] - genotype_deviate[gene_counter] - genotype_bias[gene_counter];

			//evaluating candidate
			barrier(CLK_LOCAL_MEM_FENCE);

			// =================================================================
			gpu_calc_energy(dockpars_rotbondlist_length,
					            dockpars_num_of_atoms,
					            dockpars_gridsize_x,
					            dockpars_gridsize_y,
        	            dockpars_gridsize_z,
					            dockpars_fgrids,
					            dockpars_num_of_atypes,
					            dockpars_num_of_intraE_contributors,
					            dockpars_grid_spacing,
					            dockpars_coeff_elec,
				              dockpars_qasp,
					            dockpars_coeff_desolv,
					            genotype_candidate,
					            &candidate_energy,
					            &run_id,

	        	          atom_charges_const,
			        	      atom_types_const,
		                  intraE_contributors_const,
                		  VWpars_AC_const,
		                  VWpars_BD_const,
                		  dspars_S_const,
		                  dspars_V_const,
                		  rotlist_const,
		                  ref_coords_x_const,
                		  ref_coords_y_const,
		                  ref_coords_z_const,
                		  rotbonds_moving_vectors_const,
		                  rotbonds_unit_vectors_const,
	               		  ref_orientation_quats_const);
			// =================================================================

			if (get_local_id(0) == 0)
				evaluation_cnt++;

			barrier(CLK_LOCAL_MEM_FENCE);

			if (candidate_energy < offspring_energy)//if candidate is better, success
			{
				for (gene_counter=get_local_id(0);
				     gene_counter<dockpars_num_of_genes;
			       gene_counter += NUM_OF_THREADS_PER_BLOCK)
				{
					//updating offspring_genotype
					offspring_genotype[gene_counter] = genotype_candidate[gene_counter];

					//updating genotype_bias
					genotype_bias[gene_counter] = 0.6f*genotype_bias[gene_counter] - 0.4f*genotype_deviate[gene_counter];
				}

				//thread 0 will overwrite the shared variables
				//used in the previous if condition,
				//all threads have to be after if
				barrier(CLK_LOCAL_MEM_FENCE);

				if (get_local_id(0) == 0)
				{
					offspring_energy = candidate_energy;
					cons_succ++;
					cons_fail = 0;
				}
			}
			else	//failure in both directions
			{
				for (gene_counter=get_local_id(0);
				     gene_counter<dockpars_num_of_genes;
				     gene_counter += NUM_OF_THREADS_PER_BLOCK)
					   //updating genotype_bias
					   genotype_bias[gene_counter] = 0.5f*genotype_bias[gene_counter];

				if (get_local_id(0) == 0)
				{
					cons_succ = 0;
					cons_fail++;
				}
			}
		}

		//changing rho if needed
		if (get_local_id(0) == 0)
		{
			iteration_cnt++;

			if (cons_succ >= dockpars_cons_limit)
			{
				rho *= LS_EXP_FACTOR;
				cons_succ = 0;
			}
			else
				if (cons_fail >= dockpars_cons_limit)
				{
					rho *= LS_CONT_FACTOR;
					cons_fail = 0;
				}
		}
		barrier(CLK_LOCAL_MEM_FENCE);
	}

	//updating eval counter and energy
	if (get_local_id(0) == 0)
	{
		dockpars_evals_of_new_entities[run_id*dockpars_pop_size+entity_id] += evaluation_cnt;
		dockpars_energies_next[run_id*dockpars_pop_size+entity_id] = offspring_energy;
	}

	//mapping angles
	for (gene_counter=get_local_id(0);
	     gene_counter<dockpars_num_of_genes;
	     gene_counter+=NUM_OF_THREADS_PER_BLOCK)
		   if (gene_counter >=  3)
			    map_angle(&(offspring_genotype[gene_counter]));

	//updating old offspring in population
	barrier(CLK_LOCAL_MEM_FENCE);

#if defined (ASYNC_COPY)
  async_work_group_copy(dockpars_conformations_next+(run_id*dockpars_pop_size+entity_id)*GENOTYPE_LENGTH_IN_GLOBMEM,
                        offspring_genotype,
                        dockpars_num_of_genes,0);
#else
	for (gene_counter=get_local_id(0);
	     gene_counter<dockpars_num_of_genes;
       gene_counter+=NUM_OF_THREADS_PER_BLOCK)
		   dockpars_conformations_next[(run_id*dockpars_pop_size+entity_id)*GENOTYPE_LENGTH_IN_GLOBMEM+gene_counter] = offspring_genotype[gene_counter];
#endif
}